home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Info-Mac 4
/
Info_Mac IV CD-ROM (Pacific HiTech Inc.)(August 1994).iso
/
Science
/
MAL ©P.f.Howden 1⁄1⁄89
/
3DPLOT FUNS
< prev
next >
Wrap
Text File
|
1991-02-22
|
1KB
|
23 lines
5 CLS:PRINT"3-DIMENSIONAL PLOT FUNCTIONS":PRINT"PLOTS 1-2 FUNCTIONS TYPED ON LINES 100,200":PRINT"eg. 100 Z=EXP(-(X^2+Y^2)/2)":PRINT
7 INPUT "NUMBER OF FUNCTIONS (1,2)=";N:INPUT "NUMBER OF SECTIONS=";G:INPUT "INCREMENT (>=1)=";H:G=G-1:Q=326:REM Q=SIZE FACTOR.
9 FOR I=1 TO N:PRINT"Vertical Shift Y";I;"(=0?) =";:INPUT Y(I):NEXT I:Y1=Y(1)*N+110:Y2=120-2*Y(2)
10 INPUT "MINIMUM X=";A:INPUT "MAX X=";B:INPUT "MIN Y=";C:INPUT "MAX Y=";D:INPUT "MIN Z=";E:INPUT "MAX Z=";F
25 CLS:LOCATE 1,1:PRINT "Min X=";A;", Max X=";B;", Min Y=";C;", Max Y=";D;", Min Z=";E;", Max Z=";F
30 XS=(B-A)/Q:YS=(D-C)/Q:ZS=Q/(F-E):GS=Q/G
51 FOR I=1 TO N:FOR J=0 TO G:XC=J*GS:FOR YC=0 TO Q STEP H:GOSUB 60:NEXT YC:NEXT J
52 FOR J=0 TO G:YC=J*GS:FOR XC=0 TO Q STEP H:GOSUB 60:NEXT XC:NEXT J:NEXT I
55 GOTO 55:'END
60 X=B-XS*XC:Y=C+YS*YC:ON I GOSUB 100,200:Z=-Z:L=XC/2+YC:M=(XC/2+ZS*(Z-E)-Y1+(I-1)*(Y2+Y1))*1.2/N
65 IF Z<E OR Z>F THEN RETURN
70 PSET(L,M):RETURN
100 Z=EXP(-(X*X+Y*Y)/2)
120 RETURN
200 Z=-(X^2/4+Y^2/9)
220 RETURN
'TO RUN ABOVE TRY:13 SECTIONS,INC=3(OR =1 FOR CONTINUOUS LINES),
' MIN X,Y=-3,MAX X,Y=3,MIN Z=-3.5,MAX Z=3.5
'Another beautiful example: Z=SIN(SQR(X*X+Y*Y))/SQR(X*X+Y*Y) and
' Z=(X^2/286-Y^2/286) :TRY 2,12(or more),1,0,-10,-15,15,-15,15,-1.5,1.5
MACINTOSH LISTING